16bit to ASCII HexDecimal via output routine by http://elm-chan.org
;-----------------------------------------------------------------------------;
; Universal hexdecimal string conversion (8/16/32 bit)
;
; Register Variables:
; Call: var3:0 = 8/16/24/32 bit value to be converted
;
; Result: var3:0 = <Unknown>
;
; Size: 23 words
; Clock: depends on output routine
; Stack: 2 (+output routine)
mk_h32: push var0
mov var0, var3
rcall mk_h08
pop var0
mk_h24: push var0
mov var0, var2
rcall mk_h08
pop var0
mk_h16: push var0
mov var0, var1
rcall mk_h08
pop var0
mk_h08: push var0
swap var0
rcall PC+2
pop var0
andi var0,0x0f
cpi var0,10
brcs PC+2
subi var0,-7
subi var0,-'0'
rcall xmit
ret
| file: /techref/atmel/avr/bin2asciihex16b-ec.htm, 1KB, , updated: 2007/9/14 17:36, local time: 2009/1/9 04:22,
38.103.63.57:LOG IN
|
| ©2009 These pages are served without commercial sponsorship. (No popup ads, etc...).Bandwidth abuse increases hosting cost forcing sponsorship or shutdown. This server aggressively defends against automated copying for any reason including offline viewing, duplication, etc... Please respect this requirement and DO NOT RIP THIS SITE. Questions? Please DO link to this page! Digg it! <A HREF="http://www.massmind.org/techref/atmel/avr/bin2asciihex16b-ec.htm"> Atmel AVR, atmega, Microcontroller, embedded controller, radix conversion, 16bit to ASCII HexDecimal</A> |
| Did you find what you needed? |
Welcome to massmind.org! |
|
.